To invoke the compiler with the right options, Bazel needs some knowledge about the compiler internals, such as include directories and important flags. In other words, Bazel needs a simplified model of the compiler to understand its workings.
Bazel needs to know the following:
If the compiler has support for multiple architectures, Bazel needs to configure them separately.
CcToolchainConfigInfo is a provider that provides the necessary level of granularity for configuring the behavior of Bazel‘s C++ rules. By default, Bazel automatically configures CcToolchainConfigInfo for your build, but you have the option to configure it manually. For that, you need a Starlark rule that provides the CcToolchainConfigInfo and you need to point the toolchain_config attribute of the cc_toolchain to your rule. You can create the CcToolchainConfigInfo by calling cc_common.create_cc_toolchain_config_info(). You can find Starlark constructors for all structs you’ll need in the process in @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl.
When a C++ target enters the analysis phase, Bazel selects the appropriate cc_toolchain target based on the BUILD file, and obtains the CcToolchainConfigInfo provider from the target specified in the cc_toolchain.toolchain_config attribute. The cc_toolchain target passes this information to the C++ target through a CcToolchainProvider.
For example, a compile or link action, instantiated by a rule such as cc_binary or cc_library, needs the following information:
--copt/--linkopt optionsAll of the above information except the artifacts required in the sandbox is specified in the Starlark target that the cc_toolchain points to.
The artifacts to be shipped to the sandbox are declared in the cc_toolchain target. For example, with the cc_toolchain.linker_files attribute you can specify the linker binary and toolchain libraries to ship into the sandbox.
The toolchain selection logic operates as follows:
User specifies a cc_toolchain_suite target in the BUILD file and points Bazel to the target using the --crosstool_top option.
The cc_toolchain_suite target references multiple toolchains. The values of the --cpu and --compiler flags determine which of those toolchains is selected, either based only on the --cpu flag value, or based on a joint --cpu | --compiler value. The selection process is as follows:
If the --compiler option is specified, Bazel selects the corresponding entry from the cc_toolchain_suite.toolchains attribute with --cpu | --compiler. If Bazel does not find a corresponding entry, it throws an error.
If the --compiler option is not specified, Bazel selects the corresponding entry from the cc_toolchain_suite.toolchains attribute with just --cpu.
If no flags are specified, Bazel inspects the host system and selects a --cpu value based on its findings. See the inspection mechanism code.
Once a toolchain has been selected, corresponding feature and action_config objects in the Starlark rule govern the configuration of the build (that is, items described later in this document). These messages allow the implementation of fully fledged C++ features in Bazel without modifying the Bazel binary. C++ rules support multiple unique actions documented in detail in the Bazel source code.
A feature is an entity that requires command-line flags, actions, constraints on the execution environment, or dependency alterations. A feature can be something as simple as allowing BUILD files to select configurations of flags, such as treat_warnings_as_errors, or interact with the C++ rules and include new compile actions and inputs to the compilation, such as header_modules or thin_lto.
Ideally, CcToolchainConfigInfo contains a list of features, where each feature consists of one or more flag groups, each defining a list of flags that apply to specific Bazel actions.
A feature is specified by name, which allows full decoupling of the Starlark rule configuration from Bazel releases. In other words, a Bazel release does not affect the behavior of CcToolchainConfigInfo configurations as long as those configurations do not require the use of new features.
A feature is enabled in one of the following ways:
enabled field is set to true.--feature Bazel option or features rule attribute.Features can have interdependencies, depend on command line flags, BUILD file settings, and other variables.
Dependencies are typically managed directly with Bazel, which simply enforces the requirements and manages conflicts intrinsic to the nature of the features defined in the build. The toolchain specification allows for more granular constraints for use directly within the Starlark rule that govern feature support and expansion. These are:
Actions provide the flexibility to modify the circumstances under which an action executes without assuming how the action will be run. An action_config specifies the tool binary that an action invokes, while a feature specifies the configuration (flags) that determine how that tool behaves when the action is invoked.
Features reference actions to signal which Bazel actions they affect since actions can modify the Bazel action graph. The CcToolchainConfigInfo provider contains actions that have flags and tools associated with them, such as c++-compile. Flags are assigned to each action by associating them with a feature.
Each action name represents a single type of action performed by Bazel, such as compiling or linking. There is, however, a many-to-one relationship between actions and Bazel action types, where a Bazel action type refers to a Java class that implements an action (such as CppCompileAction). In particular, the “assembler actions” and “compiler actions” in the table below are CppCompileAction, while the link actions are CppLinkAction.
AR actions assemble object files into archive libraries (.a files) via ar and encode some semantics into the name.
A action_config is a Starlark struct that describes a Bazel action by specifying the tool (binary) to invoke during the action and sets of flags, defined by features, that apply constraints to the action's execution. The action_config() constructor has the following parameters:
An action_config can require and imply other features and action_configs as dictated by the feature relationships described earlier. This behavior is similar to that of a feature.
The last two attributes are redundant against the corresponding attributes on features and are included because some Bazel actions require certain flags or environment variables and we want to avoid unnecessary action_config+feature pairs. Typically, sharing a single feature across multiple action_configs is preferred.
You can not define more than one action_config with the same action_name within the same toolchain. This prevents ambiguity in tool paths and enforces the intention behind action_config - that an action's properties are clearly described in a single place in the toolchain.
toolAnaction_config can specify a set of tools via its tools parameter. The tool() constructor takes in the following parameters:
For a given action_config, only a single tool applies its tool path and execution requirements to the Bazel action. A tool is selected by iterating through the tools attribute on an action_config until a tool with a with_feature set matching the feature configuration is found (see Feature relationships earlier in this document for more information). We recommend that you end your tool lists with a default tool that corresponds to an empty feature configuration.
Features and actions can be used together to implement Bazel actions with diverse cross-platform semantics. For example, debug symbol generation on macOS requires generating symbols in the compile action, then invoking a specialized tool during the link action to create compressed dsym archive, and then decompressing that archive to produce the application bundle and .plist files consumable by Xcode.
With Bazel, this process can instead be implemented as follows, with unbundle-debuginfo being a Bazel action:
load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
action_configs = [
action_config (
config_name = "ACTION_NAMES.cpp_link_executable",
action_name = "ACTION_NAMES.cpp_link_executable",
tools = [
tool(
with_features = [
with_feature(features=["generate-debug-symbols"]),
],
tool_path = "toolchain/mac/ld-with-dsym-packaging",
),
tool (tool_path = "toolchain/mac/ld"),
],
),
]
features = [
feature(
name = "generate-debug-symbols",
flag_sets = [
flag_set (
actions = [
"ACTION_NAMES.c_compile",
"ACTION_NAMES.cpp_compile"
],
flag_groups = [
flag_group(
flags = ["-g"],
),
],
)
],
implies = ["unbundle-debuginfo"],
),
]
This same feature can be implemented entirely differently for Linux, which uses fission, or for Windows, which produces .pdb files. For example, the implementation for fission-based debug symbol generation might look as follows:
load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
action_configs = [
action_config (
name = "ACTION_NAMES.cpp_compile",
tools = [
tool(
tool_path = "toolchain/bin/gcc",
),
],
),
]
features = [
feature (
name = "generate-debug-symbols",
requires = [with_feature_set(features = ["dbg"])],
flag_sets = [
flag_set(
actions = ["ACTION_NAMES.cpp_compile"],
flag_groups = [
flag_group(
flags = ["-gsplit-dwarf"],
),
],
),
flag_set(
actions = ["ACTION_NAMES.cpp_link_executable"],
flag_groups = [
flag_group(
flags = ["-Wl", "--gdb-index"],
),
],
),
],
),
]
CcToolchainConfigInfo allows you to bundle flags into groups that serve a specific purpose. You can specify a flag within using pre-defined variables within the flag value, which the compiler expands when adding the flag to the build command. For example:
flag_group (
flags = ["%{output_file_path}"],
)
In this case, the contents of the flag will be replaced by the output file path of the action.
Flag groups are expanded to the build command in the order in which they appear in the list, top-to-bottom, left-to-right.
For flags that need to repeat with different values when added to the build command, the flag group can iterate variables of type list. For example, the variable include_path of type list:
flag_group (
iterate_over = "include_paths",
flags = ["-I%{include_paths}"],
)
expands to -I<path> for each path element in the include_paths list. All flags (or flag_groups) in the body of a flag group declaration are expanded as a unit. For example:
flag_group (
iterate_over = "include_paths",
flags = ["-I", "%{include_paths}"],
)
expands to -I <path> for each path element in the include_paths list.
A variable can repeat multiple times. For example:
flag_group (
iterate_over = "include_paths",
flags = ["-iprefix=%{include_paths}", "-isystem=%{include_paths}"],
)
expands to:
-iprefix=<inc0> -isystem=<inc0> -iprefix=<inc1> -isystem=<inc1>
Variables can correspond to structures accessible using dot-notation. For example:
flag_group (
flags = ["-l%{libraries_to_link.name}"],
)
Structures can be nested and may also contain sequences. To prevent name clashes and to be explicit, you must specify the full path through the fields. For example:
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
],
)
Flag groups support conditional expansion based on the presence of a particular variable or its field using the expand_if_available, expand_if_not_available, expand_if_true, expand_if_false, or expand_if_equal attributes. For example:
flag_group (
iterate_over = "libraries_to_link",
flag_groups = [
flag_group (
iterate_over = "libraries_to_link.shared_libraries",
flag_groups = [
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--whole_archive"],
),
flag_group (
flags = ["-l%{libraries_to_link.shared_libraries.name}"],
),
flag_group (
expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
flags = ["--no_whole_archive"],
),
],
),
],
)
Note: The --whole_archive and --no_whole_archive options are added to the build command only when a currently iterated library has an is_whole_archive field.
CcToolchainConfigInfo referenceThis section provides a reference of build variables, features, and other information required to successfully configure C++ rules.
CcToolchainConfigInfo build variablesThe following is a reference of CcToolchainConfigInfo build variables.
Note: The Action column indicates the relevant action type, if applicable.
The following is a reference of features and their activation conditions.
This is a long list of features. The plan is to get rid of them once Crosstool in Starlark is done. For the curious reader see the implementation in CppActionConfigs, and for production toolchains consider adding no_legacy_features to make the toolchain more standalone.