diff --git a/src/test/shell/integration/python_test.sh b/src/test/shell/integration/python_test.sh
index 23c961e..1da34ef 100755
--- a/src/test/shell/integration/python_test.sh
+++ b/src/test/shell/integration/python_test.sh
@@ -183,4 +183,60 @@
   expect_log "I am Python 3"
 }
 
+# Helper function for test_select_on_python_version. Dependent on its setup.
+function do_test_select_on_python_version() {
+  flags="$1"
+  result="$2"
+  bazel run //test:main $flags \
+      &> $TEST_log || fail "bazel run failed"
+  expect_log "I am $result" "Expected version $result for flags \"$flags\""
+}
+
+function test_select_on_python_version() {
+  mkdir -p test
+
+  cat > test/BUILD << EOF
+sh_binary(name = "main",
+    srcs = select({
+        "$TOOLS_REPOSITORY//tools/python:PY2": ["py2.sh"],
+        "$TOOLS_REPOSITORY//tools/python:PY3": ["py3.sh"],
+    }),
+)
+EOF
+
+  cat > test/py2.sh << EOF
+#/bin/sh
+
+echo "I am PY2"
+EOF
+  sed s/PY2/PY3/ test/py2.sh > test/py3.sh
+  chmod u+x test/py2.sh test/py3.sh
+
+  DEFAULT_VERSION=PY2
+
+  EXPFLAG="--experimental_better_python_version_mixing=true"
+  NO_EXPFLAG="--experimental_better_python_version_mixing=false"
+
+  # --force_python and --python_version have three possible values (including
+  # not being set at all). The experimental flag has two possible values, but
+  # when it's disabled --python_version may not be set. So that's 12
+  # combinations to enumerate here.
+
+  do_test_select_on_python_version "$NO_EXPFLAG" "$DEFAULT_VERSION"
+  do_test_select_on_python_version "$NO_EXPFLAG --force_python=PY2" "PY2"
+  do_test_select_on_python_version "$NO_EXPFLAG --force_python=PY3" "PY3"
+
+  do_test_select_on_python_version "$EXPFLAG" "$DEFAULT_VERSION"
+  do_test_select_on_python_version "$EXPFLAG --force_python=PY2" "PY2"
+  do_test_select_on_python_version "$EXPFLAG --force_python=PY3" "PY3"
+
+  do_test_select_on_python_version "$EXPFLAG --python_version=PY2" "PY2"
+  do_test_select_on_python_version "$EXPFLAG --force_python=PY2 --python_version=PY2" "PY2"
+  do_test_select_on_python_version "$EXPFLAG --force_python=PY3 --python_version=PY2" "PY2"
+
+  do_test_select_on_python_version "$EXPFLAG --python_version=PY3" "PY3"
+  do_test_select_on_python_version "$EXPFLAG --force_python=PY2 --python_version=PY3" "PY3"
+  do_test_select_on_python_version "$EXPFLAG --force_python=PY3 --python_version=PY3" "PY3"
+}
+
 run_suite "Tests for the Python rules"
diff --git a/tools/python/BUILD b/tools/python/BUILD
index a344b44..62c1b80 100644
--- a/tools/python/BUILD
+++ b/tools/python/BUILD
@@ -1,3 +1,5 @@
+load(":python_version.bzl", "define_python_version_flag")
+
 package(default_visibility = ["//visibility:public"])
 
 sh_binary(
@@ -6,27 +8,15 @@
 )
 
 filegroup(
-    name = "srcs_and_embedded_tools",
-    srcs = [
-        # Tools are build from the workspace for tests.
-        "2to3.sh",
-        "BUILD",
-    ],
-    visibility = ["//visibility:private"],
-)
-
-filegroup(
     name = "srcs",
-    srcs = [
-        ":srcs_and_embedded_tools",
+    srcs = glob(["**"]) + [
         "//tools/python/runfiles:srcs",
     ],
 )
 
 filegroup(
     name = "embedded_tools",
-    srcs = [
-        ":srcs_and_embedded_tools",
+    srcs = glob(["**"]) + [
         "//tools/python/runfiles:embedded_tools",
     ],
     visibility = ["//tools:__pkg__"],
@@ -39,3 +29,48 @@
     ],
     visibility = ["//tools:__pkg__"],
 )
+
+# This target can be used to inspect the current Python major version. To use,
+# put it in the `flag_values` attribute of a `config_setting` and test it
+# against the values "PY2" or "PY3". It will always match one or the other.
+#
+# If you do not need to test any other flags in combination with the Python
+# version, then as a convenience you may use the predefined `config_setting`s
+# `@bazel_tools//python:PY2` and `@bazel_tools//python:PY3`.
+#
+# Example usage:
+#
+#     config_setting(
+#         name = "py3_on_arm",
+#         values = {"cpu": "arm"},
+#         flag_values = {"@bazel_tools//python:python_version": "PY3"},
+#     )
+#
+#     my_target(
+#         ...
+#         some_attr = select({
+#             ":py3_on_arm": ...,
+#             ...
+#         }),
+#         ...
+#     )
+#
+# Caution: Do not `select()` on the built-in command-line flags `--force_python`
+# or `--python_version`, as they do not always reflect the true Python version
+# of the current target. `select()`-ing on them can lead to action conflicts and
+# will be disallowed.
+define_python_version_flag(
+    name = "python_version",
+)
+
+config_setting(
+    name = "PY2",
+    flag_values = {":python_version": "PY2"},
+    visibility = ["//visibility:public"],
+)
+
+config_setting(
+    name = "PY3",
+    flag_values = {":python_version": "PY3"},
+    visibility = ["//visibility:public"],
+)
diff --git a/tools/python/python_version.bzl b/tools/python/python_version.bzl
new file mode 100644
index 0000000..ef72015
--- /dev/null
+++ b/tools/python/python_version.bzl
@@ -0,0 +1,126 @@
+# Copyright 2018 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Utilities for selecting the Python major version (Python 2 vs Python 3)."""
+
+_UNSET = "UNSET"
+_FALSE = "FALSE"
+_TRUE = "TRUE"
+_PY2 = "PY2"
+_PY3 = "PY3"
+
+# Keep in sync with default value of --experimental_better_python_version_mixing.
+_DEFAULT_EXPERIMENTAL_FLAG = False
+
+# Keep in sync with PythonVersion.DEFAULT_TARGET_VALUE.
+_DEFAULT_PYTHON_VERSION = "PY2"
+
+def _python_version_flag_impl(ctx):
+    # Convert the string-encoded tri-value to a boolean, where unset yields the
+    # default value.
+    experimental = {
+        _TRUE: True,
+        _FALSE: False,
+        _UNSET: _DEFAULT_EXPERIMENTAL_FLAG,
+    }[ctx.attr.experimental_flag]
+
+    # Version is determined using the same logic as in PythonOptions#getPythonVersion:
+    #   1. Under the experimental flag, consult --python_version first,
+    #      otherwise ignore it.
+    #   2. Next fall back on --force_python.
+    #   3. Final fallback is on the hardcoded default.
+    if experimental and ctx.attr.python_version_flag != _UNSET:
+        version = ctx.attr.python_version_flag
+    elif ctx.attr.force_python_flag != _UNSET:
+        version = ctx.attr.force_python_flag
+    else:
+        version = _DEFAULT_PYTHON_VERSION
+
+    if version not in ["PY2", "PY3"]:
+        fail("Internal error: _python_version_flag should only be able to " +
+             "match 'PY2' or 'PY3'")
+    return [config_common.FeatureFlagInfo(value = version)]
+
+_python_version_flag = rule(
+    implementation = _python_version_flag_impl,
+    attrs = {
+        "experimental_flag": attr.string(mandatory = True, values = [_TRUE, _FALSE, _UNSET]),
+        "force_python_flag": attr.string(mandatory = True, values = [_PY2, _PY3, _UNSET]),
+        "python_version_flag": attr.string(mandatory = True, values = [_PY2, _PY3, _UNSET]),
+    },
+)
+
+def define_python_version_flag(name):
+    """Defines the target to expose the Python version to select().
+
+    For use only by @bazel_tools//python:BUILD; see the documentation comment
+    there.
+
+    Args:
+        name: The name of the target to introduce.
+    """
+
+    # Config settings for the underlying native flags we depend on:
+    # --experimental_better_python_version_mixing, --force_python, and
+    # --python_version.
+    native.config_setting(
+        name = "_experimental_false",
+        values = {"experimental_better_python_version_mixing": "false"},
+        visibility = ["//visibility:private"],
+    )
+    native.config_setting(
+        name = "_experimental_true",
+        values = {"experimental_better_python_version_mixing": "true"},
+        visibility = ["//visibility:private"],
+    )
+    native.config_setting(
+        name = "_force_python_setting_PY2",
+        values = {"force_python": "PY2"},
+        visibility = ["//visibility:private"],
+    )
+    native.config_setting(
+        name = "_force_python_setting_PY3",
+        values = {"force_python": "PY3"},
+        visibility = ["//visibility:private"],
+    )
+    native.config_setting(
+        name = "_python_version_setting_PY2",
+        values = {"python_version": "PY2"},
+        visibility = ["//visibility:private"],
+    )
+    native.config_setting(
+        name = "_python_version_setting_PY3",
+        values = {"python_version": "PY3"},
+        visibility = ["//visibility:private"],
+    )
+
+    _python_version_flag(
+        name = name,
+        experimental_flag = select({
+            ":_experimental_false": _FALSE,
+            ":_experimental_true": _TRUE,
+            "//conditions:default": _UNSET,
+        }),
+        force_python_flag = select({
+            ":_force_python_setting_PY2": _PY2,
+            ":_force_python_setting_PY3": _PY3,
+            "//conditions:default": _UNSET,
+        }),
+        python_version_flag = select({
+            ":_python_version_setting_PY2": _PY2,
+            ":_python_version_setting_PY3": _PY3,
+            "//conditions:default": _UNSET,
+        }),
+        visibility = ["//visibility:public"],
+    )
diff --git a/tools/python/runfiles/BUILD b/tools/python/runfiles/BUILD
index 08cec71..8ef28b3 100644
--- a/tools/python/runfiles/BUILD
+++ b/tools/python/runfiles/BUILD
@@ -2,13 +2,7 @@
 
 filegroup(
     name = "srcs",
-    srcs = glob(
-        ["**"],
-        exclude = [
-            ".*",
-            "*~",
-        ],
-    ),
+    srcs = glob(["**"]),
     visibility = ["//tools/python:__pkg__"],
 )